Kerning in 335

[abrudz]

Some pairs are apparently already kerned, like f and T followed by a few letters. However, here is a function that generates all the pairs that should be kerned:

 Report←{
     all←⎕A∪⎕A ⎕C⍛∪⎕D∪∊(
         rt←'TŢŤVWŴẀẂẄYÝŶŸȲỲỸ/ƒʃΎΥΓЃΤΫϝУЎГТⓉⓋⓌⓎ⫽∕√∛∜'
         rm←'rvwy)-–—}DÐĎĐGĜĞĠĢǦǴḠOÒÓÔÕÖŌŎŐǑȮ0»ÞƆ®©··̇ΌΟΘΦγθτϷϽϿОФЭуỳⒹⒼⓄⓡⓥⓦⓨ⦄⦆−'
         rb←'AÀÁÂÃÄÅĀĂǍǺȦẬLĹĻĽŁ,‚.\_„…ıɩΆ₀₁₂₃₄₅₆₇₈₉ΔΛλⒶⓁ⑊⧵∆⍙'
         rtm←'FJĴP"''’”‘“‛7ØǾÿȳďŕŗŦŵºª°⁰¹²³⁴⁵⁶⁷⁸⁹ΐΡΨδϊϜЈРгтѓўℙⒻⒿⓅ∮⌿'
         rtb←'CÇĆĈĊČEÈÉÊËĒĖĘĚȨẼIÌÍÎÏĨĪĬĮİǏKĶǨXZŹŻŽ([{£ƐƖƩΈΕΊΖΚΣΧΪІЇζξϹϾЀЁЌЕЖКСХ€ℂℤⒸⒺⒾⓀⓍⓏ⟦⟨'
         rmb←'aàȧɐɑɒæbcɔçċ¢eèėǝɘəȩɛɜghkķĸmnņʼnŋǹoòȯøœpqsşșuùųuxzij:;QþĿµΏΩαεικμνοπρςσυφχψωϕϖϱϲϴϵ϶ϸϼЪЬавежзиклмнопрсфхчшщъыьэюяѐєѕᴊẁℚ⍺⍵⍶⍹Ⓠⓐⓑⓒⓔⓖⓗⓚⓜⓝⓞⓟⓠⓢⓤⓤⓧⓩ⍀ℎ'

         rd←'gĝğġģqQ()[]{}\,‚_„ĄąĘijŋųǧǵ₀₁₂₃₄₅₆₇₈₉ηήζξςχϼЦЩцщℚ⍶⍹ⒶⒷⒸⒹⒺⒻⒼⒽⒾⒿⓀⓁⓂⓃⓄⓅⓆⓇⓈⓉⓊⓋⓌⓍⓎⓏⓐⓑⓒⓓⓔⓕⓖⓗⓘⓙⓚⓛⓜⓝⓞⓟⓠⓡⓢⓣⓤⓥⓦⓧⓨⓩ⟦⟧⟨⟩⑊⦃⦄⦅⦆⦋⦌'

         lt←'\TŢŤVWŴYÝŶŸȲΎΥỲỸΤΫТЪⓉⓋⓌⓎ⑊⧵'
         lm←'vwy-–—CÇĆĈĊČGĜĞĠĢǴḠOÒÓÔÕÖŌŎŐǑȮQ0({«®©··⁰¹²³⁴⁵⁶⁷⁸⁹ΘΦγθντϹϾЄСФтуъℚⒸⒼⓄⓆⓥⓦⓨ⦃⦅−'
         lb←'AÀÁÂÃÄÅÆǢǼĀĂǺȦẬ,.‚„_/…ıƒɩʃΔΛϝДᴊⒶ⫽∕∆⍙'
         ltm←'4"''’”‘“‛7ÿȳŦŵºª°̇ΌΟΐΨϊЧўẅỹ⍀'
         ltb←')}JĴIÌÍÎÏĨĪĬĮİǏXZŹŻŽ3]ƆƖƩΆΊΖΣΧΪІЇλϽϿЈУЎЖЗХℤⒾⒿⓍⓏ⟧⟩'
         lmb←'aáȧɐɑɒæǽcɔçćċ¢dďeéėǝɘəȩɛɜgĸmnņńŋoóȯøǿœpqrŕŗsşśșuúųxz:;ØǾµΩάέαηήεικμοπρςσυφχψωόύώϕϖϱϲϴϵ϶авежзиклмнопрсфхчшщыьэюяѓєѕẃ⍺⍵⍶⍹ⓐⓒⓓⓔⓖⓜⓝⓞⓟⓠⓡⓢⓤⓧⓩ√⌿ℎ'

         ld←'jĵǰȷϳј'
     )
     C←{⊂⍤⍋⍛⌷⊃,/,¨∘.,/⍵}
     strong←C[
         rt lb
         rb lt
         (all~rd,ld)'j'
     ]

     slight←C[
         rm ltb
         rtm lb
         rtb lm
         rmb lt
         rt lmb
         rb ltm
     ]

     '# Strong'⊂⍛,strong,'' '# Slight:',slight
 }

The first letter of each group name (r/l) refers to the left/right edge. The remaining (t/m/b) indicates where that group's glyphs have ink. rd is the special group for glyphs that descend below the baseline on the right, and ld is for j-like characters that reach in under the letter on their left.