Enable type resolution for Detekt behind the enable_type_resolution attr

Author: ryanulep

MODULE.bazel

@@ -1,6 +1,6 @@
 module(
     name = "rules_detekt",
-    version = "0.8.1.1",
+    version = "0.8.1.1.RYANULEP",
     compatibility_level = 1,
     repo_name = "bazel_rules_detekt",
 )
@@ -11,6 +11,7 @@ detekt = use_extension("//detekt:extensions.bzl", "detekt")
 use_repo(detekt, "detekt_cli_all")
 
 bazel_dep(name = "rules_java", version = "9.0.3")
+bazel_dep(name = "rules_android", version = "0.7.1")
 bazel_dep(name = "rules_proto", version = "7.1.0")
 bazel_dep(name = "rules_jvm_external", version = "6.9")
 bazel_dep(name = "bazel_worker_api", version = "0.0.10")
@@ -22,7 +23,7 @@ maven.install(
     name = "rules_detekt_dependencies",
     artifacts = [
         "junit:junit:4.13.2",
-        "io.gitlab.arturbosch.detekt:detekt-formatting:1.23.1",
+        "io.gitlab.arturbosch.detekt:detekt-formatting:1.23.8",
     ],
     fail_if_repin_required = True,
     lock_file = "//:maven_install.json",

README.md

@@ -9,7 +9,7 @@ for the [Bazel build system](https://bazel.build).
 - HTML, text, XML, Markdown, and SARIF reports;
 - [plugins](https://detekt.dev/docs/extensions/extensions/);
 - customizable Detekt version and JVM flags;
-- [persistent workers](https://blog.bazel.build/2015/12/10/java-workers.html) support;
+- [type resolution](https://detekt.dev/docs/gettingstarted/type-resolution/) with JVM and Android classpath support;
 - baseline generation via `detekt_create_baseline`;
 - configuration options via [attributes](docs/attrs.md).
 
@@ -127,15 +127,15 @@ and it supports standard Bazel test flags such as `--test_output=all`.
 
 ### `detekt` vs `detekt_test`
 
-|                     | `detekt`                  | `detekt_test`                          |
-| ------------------- | ------------------------- | -------------------------------------- |
-| Bazel rule type     | build rule                | test rule                              |
-| Run with            | `bazel build`             | `bazel test`                           |
-| Included in         | `bazel build //...`       | `bazel test //...`                     |
-| Violation behaviour | build action fails        | test fails; build action always passes |
-| Text report         | printed when action fails | printed to test output when test fails |
-| Result caching      | yes                       | yes                                    |
-| Bazel test flags    | n/a                       | yes (`--test_output`, etc.)            |
+|                     | `detekt`                  | `detekt_test`                                                         |
+| ------------------- | ------------------------- |-----------------------------------------------------------------------|
+| Bazel rule type     | build rule                | test rule                                                             |
+| Run with            | `bazel build`             | `bazel test`                                                          |
+| Included in         | `bazel build //...`       | `bazel test //...`                                                    |
+| Violation behavior  | build action fails        | test fails; build action always passes even if violations are present |
+| Text report         | printed when action fails | printed to test output when test fails                                |
+| Result caching      | yes                       | yes                                                                   |
+| Bazel test flags    | n/a                       | yes (`--test_output`, etc.)                                           |
 
 Use `detekt` when you want violations to block builds the same way a compiler error does. Use
 `detekt_test` when you want Detekt to run alongside your test suite and report results through
@@ -177,8 +177,9 @@ detekt_test(
 
 ### Configuration Options
 
-All three rules share the same configuration options. In addition to `srcs`, `cfgs`, `baseline`, `plugins`,
-and report options, most attributes correspond directly to
+All three rules share the same configuration options. In addition to `srcs`, `deps`, `cfgs`,
+`baseline`, `plugins`, `enable_type_resolution`, `is_android`, and report options, most attributes
+correspond directly to
 [Detekt CLI flags](https://detekt.dev/docs/1.23.8/gettingstarted/cli/#use-the-cli) and pass them
 through when explicitly set.
 
@@ -187,7 +188,7 @@ More information can be found in the [attributes](docs/attrs.md).
 ### Reports
 
 A plain-text report (`{name}_detekt_report.txt`) is **always** generated. Other report formats are
-available for opt-in via configuration options..
+available for opt-in via attributes.
 
 ## Advanced Configuration
 
@@ -207,7 +208,7 @@ detekt.detekt_version(
 use_repo(detekt, "detekt_cli_all")
 ```
 
-To download Detekt from a custom location (e.g. an internal mirror), use the `url_templates` parameter:
+To download Detekt from a custom location (e.g., an internal mirror), use the `url_templates` parameter:
 
 ```python
 detekt = use_extension("@rules_detekt//detekt:extensions.bzl", "detekt")
@@ -252,17 +253,27 @@ rules_detekt_dependencies(
 
 Each template may contain `{version}` which will be replaced with the version string.
 
-### JVM Flags
+### Toolchain
+
+The detekt toolchain controls JVM flags, the JVM bytecode target version, and the Kotlin language
+version compatibility. The defaults are:
 
-The default toolchain uses `-Xms16m -Xmx128m`. To customize JVM flags, define your own toolchain
-in a `BUILD` file:
+| Setting            | Default  |
+| ------------------ | -------- |
+| `jvm_flags`        | `-Xms16m -Xmx128m` |
+| `jvm_target`       | `1.8`    |
+| `language_version` | `2.0`    |
+
+To override any of these, define a custom toolchain in a `BUILD` file:
 
 ```python
 load("@rules_detekt//detekt:toolchain.bzl", "detekt_toolchain")
 
 detekt_toolchain(
     name = "my_detekt_toolchain_impl",
     jvm_flags = ["-Xms16m", "-Xmx512m"],
+    jvm_target = "11",
+    language_version = "1.9",
 )
 
 toolchain(
@@ -354,49 +365,50 @@ detekt_test(
 )
 ```
 
-### JVM Target
+### Type Resolution
+
+Type resolution enables more advanced static analysis by giving Detekt access to the full
+compilation classpath — including return types, nullability, and symbol information. Rules
+requiring it are annotated with `@RequiresFullAnalysis` in Detekt's source.
 
-Use `jvm_target` to set the JVM bytecode target version that matches what was used during compilation.
-This defaults to `1.8` if not explicitly set:
+Type resolution is **enabled by default** (`enable_type_resolution = True`). When enabled, the
+appropriate bootclasspath (JDK or Android SDK) is always included. To also include your project's
+library dependencies on the classpath, pass them via `deps`:
 
 ```python
+load("@rules_detekt//detekt:defs.bzl", "detekt_test")
+
 detekt_test(
     name = "my_detekt",
     srcs = glob(["src/main/kotlin/**/*.kt"]),
-    jvm_target = "11",
+    deps = [":my_library"],  # provides the classpath for type resolution
 )
 ```
 
-### Language Version
-
-Detekt will report errors for any language features introduced after the specified version if
-`language_version` is specified. When unset, no compatibility restriction is applied:
+For **Android targets**, set `is_android = True` to include the Android SDK jar in the classpath:
 
 ```python
 detekt_test(
     name = "my_detekt",
     srcs = glob(["src/main/kotlin/**/*.kt"]),
-    language_version = "2.0",
+    deps = [":my_android_library"],
+    is_android = True,
 )
 ```
 
-### Type Resolution
-
-Type resolution enables more advanced static analysis by giving Detekt access to the full compilation classpath,
-including return types, nullability, and symbol information — capabilities that match those of the Kotlin compiler
-itself. Rules requiring it are annotated with `@RequiresFullAnalysis` in Detekt's source.
-
-Use `jvm_target` and `language_version` to match the compilation settings of your project:
+To opt out of type resolution entirely (syntax-only analysis), set `enable_type_resolution = False`:
 
 ```python
 detekt_test(
     name = "my_detekt",
     srcs = glob(["src/main/kotlin/**/*.kt"]),
-    jvm_target = "11",
-    language_version = "2.0",
+    enable_type_resolution = False,
 )
 ```
 
+`jvm_target` and `language_version` are toolchain-level settings — see
+[Toolchain](#toolchain) for how to configure them.
+
 ### Reports
 
 By default, Detekt generates a text report internally (used for console output). To export reports as build outputs,

WORKSPACE.bazel

@@ -37,7 +37,7 @@ maven_install(
     name = "rules_detekt_dependencies",
     artifacts = [
         "junit:junit:4.13.2",
-        "io.gitlab.arturbosch.detekt:detekt-formatting:1.23.1",
+        "io.gitlab.arturbosch.detekt:detekt-formatting:1.23.8",
     ],
     fail_if_repin_required = True,
     maven_install_json = "//:maven_install.json",
@@ -52,9 +52,9 @@ pinned_maven_install()
 
 ## Skylib
 
-skylib_version = "1.4.1"
+skylib_version = "1.8.2"
 
-skylib_sha = "b8a1527901774180afc798aeb28c4634bdccf19c4d98e7bdd1ce79d1fe9aaad7"
+skylib_sha = "6e78f0e57de26801f6f564fa7c4a48dc8b36873e416257a92bbb0937eeac8446"
 
 http_archive(
     name = "bazel_skylib",
@@ -70,9 +70,9 @@ bazel_skylib_workspace()
 
 ## Stardoc
 
-stardoc_version = "0.5.3"
+stardoc_version = "0.7.2"
 
-stardoc_sha = "3fd8fec4ddec3c670bd810904e2e33170bedfe12f90adf943508184be458c8bb"
+stardoc_sha = "0e1ed4a98f26e718776bd64d053d02bb34d98572ccd03d6ba355112a1205706b"
 
 http_archive(
     name = "io_bazel_stardoc",

detekt/defs.bzl

@@ -2,6 +2,7 @@
 Rule declarations.
 """
 
+load("@rules_android//rules:utils.bzl", "get_android_sdk")
 load("@rules_java//java:defs.bzl", "JavaInfo")
 
 _ATTRS = {
@@ -10,11 +11,19 @@ _ATTRS = {
         executable = True,
         cfg = "exec",
     ),
+    "_java_toolchain": attr.label(
+        default = Label("@bazel_tools//tools/jdk:current_java_toolchain"),
+    ),
     "srcs": attr.label_list(
         mandatory = True,
-        allow_files = [".kt", ".kts"],
+        allow_files = [".kt", ".kts", ".java"],
         allow_empty = False,
-        doc = "Kotlin source code files to analyze.",
+        doc = "Kotlin and Java source code files to analyze. Java files are included to support type resolution in mixed-language projects.",
+    ),
+    "deps": attr.label_list(
+        default = [],
+        doc = "Dependencies to provide to Detekt for classpath type resolution.",
+        providers = [JavaInfo],
     ),
     "plugins": attr.label_list(
         default = [],
@@ -55,6 +64,10 @@ _ATTRS = {
         default = False,
         doc = "Disables default rule sets.",
     ),
+    "enable_type_resolution": attr.bool(
+        default = True,
+        doc = "Enables type resolution for more advanced static analysis. When enabled, the classpath is constructed from `deps` and the appropriate bootclasspath (Android SDK or JDK) is included. When disabled, no classpath is passed to Detekt and only syntax-based rules are applied.",
+    ),
     "excludes": attr.string_list(
         default = [],
         doc = "Globbing patterns describing paths to exclude from the analysis.",
@@ -63,23 +76,13 @@ _ATTRS = {
         default = [],
         doc = "Globbing patterns describing paths to include in the analysis. Useful in combination with 'excludes' patterns.",
     ),
-    "jvm_target": attr.string(
-        default = "1.8",
-        values = ["1.8", "9", "10", "11", "12", "13", "14", "15", "16", "17", "18", "19", "20"],
-        doc = "EXPERIMENTAL: Target version of the generated JVM bytecode that was generated during compilation and is now being used for type resolution (1.8, 9, 10, ..., 20)",
-    ),
-    "language_version": attr.string(
-        default = "",
-        values = ["", "1.0", "1.1", "1.2", "1.3", "1.4", "1.5", "1.6", "1.7", "1.8", "1.9", "2.0", "2.1", "2.2"],
-        doc = "EXPERIMENTAL: Compatibility mode for Kotlin language version X.Y, reports errors for all language features that came out later",
-    ),
     "max_issues": attr.int(
         default = -1,
         doc = "Passes only when found issues count does not exceed specified issues count.",
     ),
     "parallel": attr.bool(
         default = False,
-        doc = "Enables parallel compilation and analysis of source files. Do some benchmarks first before enabling this flag. Heuristics show performance benefits starting from 2000 lines of Kotlin code.",
+        doc = "Enables parallel compilation and analysis of source files. Do some benchmarks first before enabling this flag. Heuristics show performance benefits starting from 2,000 lines of Kotlin code.",
     ),
     "txt_report": attr.bool(
         default = False,
@@ -101,10 +104,22 @@ _ATTRS = {
         default = False,
         doc = "Enables / disables the SARIF report generation. The report file name is `{target_name}_detekt_report.sarif`.",
     ),
+    "is_android": attr.bool(
+        default = False,
+        doc = "Whether the target is an Android target. When enabled, the Android SDK jar is included in the classpath for type resolution.",
+    ),
 }
 
 TOOLCHAIN_TYPE = Label("//detekt:toolchain_type")
 
+_ANDROID_SDK_TOOLCHAIN_TYPE = "@rules_android//toolchains/android_sdk:toolchain_type"
+
+_TOOLCHAINS = [
+    TOOLCHAIN_TYPE,
+    config_common.toolchain_type(_ANDROID_SDK_TOOLCHAIN_TYPE, mandatory = False),
+    "@bazel_tools//tools/jdk:toolchain_type",
+]
+
 def _impl(
         ctx,
         run_as_test_target = False,
@@ -182,10 +197,10 @@ def _impl(
     if ctx.attr.includes:
         detekt_arguments.add_joined("--includes", ctx.attr.includes, join_with = ",")
 
-    detekt_arguments.add("--jvm-target", ctx.attr.jvm_target)
+    detekt_arguments.add("--jvm-target", ctx.toolchains[TOOLCHAIN_TYPE].jvm_target)
 
-    if ctx.attr.language_version:
-        detekt_arguments.add("--language-version", ctx.attr.language_version)
+    if ctx.toolchains[TOOLCHAIN_TYPE].language_version:
+        detekt_arguments.add("--language-version", ctx.toolchains[TOOLCHAIN_TYPE].language_version)
 
     if ctx.attr.max_issues >= 0:
         detekt_arguments.add("--max-issues", ctx.attr.max_issues)
@@ -196,8 +211,38 @@ def _impl(
     if run_as_test_target:
         detekt_arguments.add("--run-as-test-target")
 
-    action_inputs.extend(ctx.files.plugins)
-    detekt_arguments.add_joined("--plugins", ctx.files.plugins, join_with = ",")
+    # Supports android_binary() as plugins attr, which is not a jar.
+    plugins = depset([], transitive = [dep[JavaInfo].transitive_runtime_jars for dep in ctx.attr.plugins])
+    action_inputs.extend(plugins.to_list())
+    detekt_arguments.add_joined("--plugins", plugins, join_with = ",")
+
+    if ctx.attr.enable_type_resolution:
+        filtered_classpath = []
+
+        if ctx.attr.is_android:
+            # Android SDK is needed for resolving Android-specific types
+            if not ctx.toolchains[_ANDROID_SDK_TOOLCHAIN_TYPE]:
+                fail("is_android = True requires a registered Android SDK toolchain. " +
+                     "See https://github.com/bazelbuild/rules_android for setup instructions.")
+            android_jar = get_android_sdk(ctx).android_jar
+            action_inputs.append(android_jar)
+            filtered_classpath.append(android_jar.path)
+        else:
+            # JDK platform jar is needed for resolving core types
+            bootclasspath_files = ctx.attr._java_toolchain[java_common.JavaToolchainInfo].bootclasspath.to_list()
+            action_inputs.extend(bootclasspath_files)
+            filtered_classpath.extend([f.path for f in bootclasspath_files])
+
+        # compile_jars should contain mostly ijar/header jars that are faster to load onto the classpath
+        classpath = depset([], transitive = [dep[JavaInfo].transitive_compile_time_jars for dep in ctx.attr.deps]).to_list()
+        action_inputs.extend(classpath)
+        for file in classpath:
+            # Dependencies on AP may incorrectly bring guava JRE to classpath, make sure it's filtered out
+            if "com/google/guava/guava/" in file.path:
+                continue
+            filtered_classpath.append(file.path)
+
+        detekt_arguments.add("--classpath", ":".join(filtered_classpath))
 
     txt_report = ctx.actions.declare_file("{}_detekt_report.txt".format(ctx.label.name))
     action_outputs.append(txt_report)
@@ -285,21 +330,21 @@ detekt = rule(
     implementation = _detekt_impl,
     attrs = _ATTRS,
     provides = [DefaultInfo],
-    toolchains = [TOOLCHAIN_TYPE],
+    toolchains = _TOOLCHAINS,
 )
 
 detekt_create_baseline = rule(
     implementation = _detekt_create_baseline_impl,
     attrs = _ATTRS,
     provides = [DefaultInfo],
-    toolchains = [TOOLCHAIN_TYPE],
+    toolchains = _TOOLCHAINS,
     executable = True,
 )
 
 detekt_test = rule(
     implementation = _detekt_test_impl,
     attrs = _ATTRS,
     provides = [DefaultInfo],
-    toolchains = [TOOLCHAIN_TYPE],
+    toolchains = _TOOLCHAINS,
     test = True,
 )