Cannot configure file using vertico-multiform-categories

[bjourne]

This is my working Vertico setup. I'm not using any related packages:

(use-package vertico
  :ensure t
  :custom
  (vertico-cycle t)
  (vertico-count 20)
  :init
  (vertico-mode)
  :config
  (vertico-multiform-mode))
(defun my/sort-files (candidates)
  (let ((dirs (seq-filter #'file-directory-p candidates))
        (files (seq-remove #'file-directory-p candidates)))
    (append (sort dirs #'string-lessp)
            (sort files #'string-lessp))))
(setq vertico-multiform-categories
      '((file (vertico-sort-function . my/sort-files))))

However, if I change the last sexp to

(setq vertico-multiform-categories
       '((file (vertico-sort-function . my/sort-files)
	      (:keymap . vertico-directory-map))))

directories are no longer sorted before files.

[minad]

I cannot reproduce this. Do you have any insights on what could be wrong? Do you use the newest versions? You could also use vertico-sort-directories-first.

[bjourne]

Emacs 30.2 and Vertico 20260309.1549. vertico-sort-directories-first was what I tried first but it doesn't also sort alphabetically

[minad]

But you made sure that the function is in fact called (M-x trace-function)? Please try to reproduce starting from emacs -Q.

[bjourne]

Yes, trace-function shows that my/sort-files is called. Here is the entirety of my configuration:

(setq user-emacs-directory (expand-file-name "~/.config/emacs/lisp/"))
(setq package-user-dir (expand-file-name "~/.config/emacs/packages/"))

;; Must call this
(require 'package)
(package-initialize)

(use-package vertico
  :ensure t
  :custom
  (vertico-cycle t)
  (vertico-count 20)
  :init
  (vertico-mode)
  :config
  (vertico-multiform-mode))
(defun my/sort-files (candidates)
  (let ((dirs (seq-filter #'file-directory-p candidates))
        (files (seq-remove #'file-directory-p candidates)))
    (append (sort dirs #'string-lessp)
            (sort files #'string-lessp))))

;; This does not work
(setq vertico-multiform-categories
       '((file (vertico-sort-function . my/sort-files)
	      (:keymap . vertico-directory-map))))

With :keymap:

Without:

[minad]

This works in my test:

(vertico-mode)
(vertico-multiform-mode)
(setq vertico-multiform-categories
       '((file (vertico-sort-function . vertico-sort-directories-first)
	       (:keymap . vertico-directory-map))))

Your sort function is incorrect.

[bjourne]

This is how it looks for me:

Directories are indeed first but not in alphabetical order. I'll try on my other computer and see if it works better there.

[minad]

Yes, it sorts first by length and history.

[bjourne]

Sorry, I see. You can't use file-directory-p and need to do string matching:

(defun my/sort-files (els)
  (let ((is-dir (apply-partially #'string-suffix-p "/")))
    (append (sort (seq-filter is-dir els))
	          (sort (seq-remove is-dir els)))))